<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/env perl
# SPDX-License-Identifier: GPL-2.0

use strict;
use Pod::Usage;
use Getopt::Long;
use File::Find;
use Fcntl ':mode';

my $help;
my $man;
my $debug;
my $prefix="Documentation/ABI";

GetOptions(
	"debug|d+" =&gt; \$debug,
	"dir=s" =&gt; \$prefix,
	'help|?' =&gt; \$help,
	man =&gt; \$man
) or pod2usage(2);

pod2usage(1) if $help;
pod2usage(-exitstatus =&gt; 0, -verbose =&gt; 2) if $man;

pod2usage(2) if (scalar @ARGV &lt; 1 || @ARGV &gt; 2);

my ($cmd, $arg) = @ARGV;

pod2usage(2) if ($cmd ne "search" &amp;&amp; $cmd ne "rest" &amp;&amp; $cmd ne "validate");
pod2usage(2) if ($cmd eq "search" &amp;&amp; !$arg);

require Data::Dumper if ($debug);

my %data;

#
# Displays an error message, printing file name and line
#
sub parse_error($$$$) {
	my ($file, $ln, $msg, $data) = @_;

	print STDERR "file $file#$ln: $msg at\n\t$data";
}

#
# Parse an ABI file, storing its contents at %data
#
sub parse_abi {
	my $file = $File::Find::name;

	my $mode = (stat($file))[2];
	return if ($mode &amp; S_IFDIR);
	return if ($file =~ m,/README,);

	my $name = $file;
	$name =~ s,.*/,,;

	my $nametag = "File $name";
	$data{$nametag}-&gt;{what} = "File $name";
	$data{$nametag}-&gt;{type} = "File";
	$data{$nametag}-&gt;{file} = $name;
	$data{$nametag}-&gt;{filepath} = $file;
	$data{$nametag}-&gt;{is_file} = 1;

	my $type = $file;
	$type =~ s,.*/(.*)/.*,$1,;

	my $what;
	my $new_what;
	my $tag;
	my $ln;
	my $xrefs;
	my $space;
	my @labels;
	my $label;

	print STDERR "Opening $file\n" if ($debug &gt; 1);
	open IN, $file;
	while(&lt;IN&gt;) {
		$ln++;
		if (m/^(\S+)(:\s*)(.*)/i) {
			my $new_tag = lc($1);
			my $sep = $2;
			my $content = $3;

			if (!($new_tag =~ m/(what|where|date|kernelversion|contact|description|users)/)) {
				if ($tag eq "description") {
					# New "tag" is actually part of
					# description. Don't consider it a tag
					$new_tag = "";
				} elsif ($tag ne "") {
					parse_error($file, $ln, "tag '$tag' is invalid", $_);
				}
			}

			# Invalid, but it is a common mistake
			if ($new_tag eq "where") {
				parse_error($file, $ln, "tag 'Where' is invalid. Should be 'What:' instead", $_);
				$new_tag = "what";
			}

			if ($new_tag =~ m/what/) {
				$space = "";
				if ($tag =~ m/what/) {
					$what .= ", " . $content;
				} else {
					parse_error($file, $ln, "What '$what' doesn't have a description", "") if ($what &amp;&amp; !$data{$what}-&gt;{description});

					$what = $content;
					$label = $content;
					$new_what = 1;
				}
				push @labels, [($content, $label)];
				$tag = $new_tag;

				push @{$data{$nametag}-&gt;{xrefs}}, [($content, $label)] if ($data{$nametag}-&gt;{what});
				next;
			}

			if ($tag ne "" &amp;&amp; $new_tag) {
				$tag = $new_tag;

				if ($new_what) {
					@{$data{$what}-&gt;{label}} = @labels if ($data{$nametag}-&gt;{what});
					@labels = ();
					$label = "";
					$new_what = 0;

					$data{$what}-&gt;{type} = $type;
					$data{$what}-&gt;{file} = $name;
					$data{$what}-&gt;{filepath} = $file;
					print STDERR "\twhat: $what\n" if ($debug &gt; 1);
				}

				if (!$what) {
					parse_error($file, $ln, "'What:' should come first:", $_);
					next;
				}
				if ($tag eq "description") {
					next if ($content =~ m/^\s*$/);
					if ($content =~ m/^(\s*)(.*)/) {
						my $new_content = $2;
						$space = $new_tag . $sep . $1;
						while ($space =~ s/\t+/' ' x (length($&amp;) * 8 - length($`) % 8)/e) {}
						$space =~ s/./ /g;
						$data{$what}-&gt;{$tag} .= "$new_content\n";
					}
				} else {
					$data{$what}-&gt;{$tag} = $content;
				}
				next;
			}
		}

		# Store any contents before tags at the database
		if (!$tag &amp;&amp; $data{$nametag}-&gt;{what}) {
			$data{$nametag}-&gt;{description} .= $_;
			next;
		}

		if ($tag eq "description") {
			if (!$data{$what}-&gt;{description}) {
				next if (m/^\s*\n/);
				if (m/^(\s*)(.*)/) {
					$space = $1;
					while ($space =~ s/\t+/' ' x (length($&amp;) * 8 - length($`) % 8)/e) {}
					$data{$what}-&gt;{$tag} .= "$2\n";
				}
			} else {
				my $content = $_;
				if (m/^\s*\n/) {
					$data{$what}-&gt;{$tag} .= $content;
					next;
				}

				while ($content =~ s/\t+/' ' x (length($&amp;) * 8 - length($`) % 8)/e) {}
				$space = "" if (!($content =~ s/^($space)//));

				# Compress spaces with tabs
				$content =~ s&lt;^ {8}&gt; &lt;\t&gt;;
				$content =~ s&lt;^ {1,7}\t&gt; &lt;\t&gt;;
				$content =~ s&lt; {1,7}\t&gt; &lt;\t&gt;;
				$data{$what}-&gt;{$tag} .= $content;
			}
			next;
		}
		if (m/^\s*(.*)/) {
			$data{$what}-&gt;{$tag} .= "\n$1";
			$data{$what}-&gt;{$tag} =~ s/\n+$//;
			next;
		}

		# Everything else is error
		parse_error($file, $ln, "Unexpected line:", $_);
	}
	$data{$nametag}-&gt;{description} =~ s/^\n+//;
	close IN;
}

#
# Outputs the book on ReST format
#

my %labels;

sub output_rest {
	foreach my $what (sort {
				($data{$a}-&gt;{type} eq "File") cmp ($data{$b}-&gt;{type} eq "File") ||
				$a cmp $b
			       } keys %data) {
		my $type = $data{$what}-&gt;{type};
		my $file = $data{$what}-&gt;{file};
		my $filepath = $data{$what}-&gt;{filepath};

		my $w = $what;
		$w =~ s/([\(\)\_\-\*\=\^\~\\])/\\$1/g;


		foreach my $p (@{$data{$what}-&gt;{label}}) {
			my ($content, $label) = @{$p};
			$label = "abi_" . $label . " ";
			$label =~ tr/A-Z/a-z/;

			# Convert special chars to "_"
			$label =~s/([\x00-\x2f\x3a-\x40\x5b-\x60\x7b-\xff])/_/g;
			$label =~ s,_+,_,g;
			$label =~ s,_$,,;

			# Avoid duplicated labels
			while (defined($labels{$label})) {
			    my @chars = ("A".."Z", "a".."z");
			    $label .= $chars[rand @chars];
			}
			$labels{$label} = 1;

			$data{$what}-&gt;{label} .= $label;

			printf ".. _%s:\n\n", $label;

			# only one label is enough
			last;
		}


		$filepath =~ s,.*/(.*/.*),\1,;;
		$filepath =~ s,[/\-],_,g;;
		my $fileref = "abi_file_".$filepath;

		if ($type eq "File") {
			my $bar = $w;
			$bar =~ s/./-/g;

			print ".. _$fileref:\n\n";
			print "$w\n$bar\n\n";
		} else {
			my @names = split /\s*,\s*/,$w;

			my $len = 0;

			foreach my $name (@names) {
				$len = length($name) if (length($name) &gt; $len);
			}

			print "What:\n\n";

			print "+-" . "-" x $len . "-+\n";
			foreach my $name (@names) {
				printf "| %s", $name . " " x ($len - length($name)) . " |\n";
				print "+-" . "-" x $len . "-+\n";
			}
			print "\n";
		}

		print "Defined on file :ref:`$file &lt;$fileref&gt;`\n\n" if ($type ne "File");

		my $desc = $data{$what}-&gt;{description};
		$desc =~ s/^\s+//;

		# Remove title markups from the description, as they won't work
		$desc =~ s/\n[\-\*\=\^\~]+\n/\n/g;

		if (!($desc =~ /^\s*$/)) {
			if ($desc =~ m/\:\n/ || $desc =~ m/\n[\t ]+/  || $desc =~ m/[\x00-\x08\x0b-\x1f\x7b-\xff]/) {
				# put everything inside a code block
				$desc =~ s/\n/\n /g;

				print "::\n\n";
				print " $desc\n\n";
			} else {
				# Escape any special chars from description
				$desc =~s/([\x00-\x08\x0b-\x1f\x21-\x2a\x2d\x2f\x3c-\x40\x5c\x5e-\x60\x7b-\xff])/\\$1/g;

				print "$desc\n\n";
			}
		} else {
			print "DESCRIPTION MISSING for $what\n\n" if (!$data{$what}-&gt;{is_file});
		}

		if ($data{$what}-&gt;{xrefs}) {
			printf "Has the following ABI:\n\n";

			foreach my $p(@{$data{$what}-&gt;{xrefs}}) {
				my ($content, $label) = @{$p};
				$label = "abi_" . $label . " ";
				$label =~ tr/A-Z/a-z/;

				# Convert special chars to "_"
				$label =~s/([\x00-\x2f\x3a-\x40\x5b-\x60\x7b-\xff])/_/g;
				$label =~ s,_+,_,g;
				$label =~ s,_$,,;

				# Escape special chars from content
				$content =~s/([\x00-\x1f\x21-\x2f\x3a-\x40\x7b-\xff])/\\$1/g;

				print "- :ref:`$content &lt;$label&gt;`\n\n";
			}
		}
	}
}

#
# Searches for ABI symbols
#
sub search_symbols {
	foreach my $what (sort keys %data) {
		next if (!($what =~ m/($arg)/));

		my $type = $data{$what}-&gt;{type};
		next if ($type eq "File");

		my $file = $data{$what}-&gt;{filepath};

		my $bar = $what;
		$bar =~ s/./-/g;

		print "\n$what\n$bar\n\n";

		my $kernelversion = $data{$what}-&gt;{kernelversion};
		my $contact = $data{$what}-&gt;{contact};
		my $users = $data{$what}-&gt;{users};
		my $date = $data{$what}-&gt;{date};
		my $desc = $data{$what}-&gt;{description};
		$kernelversion =~ s/^\s+//;
		$contact =~ s/^\s+//;
		$users =~ s/^\s+//;
		$users =~ s/\n//g;
		$date =~ s/^\s+//;
		$desc =~ s/^\s+//;

		printf "Kernel version:\t\t%s\n", $kernelversion if ($kernelversion);
		printf "Date:\t\t\t%s\n", $date if ($date);
		printf "Contact:\t\t%s\n", $contact if ($contact);
		printf "Users:\t\t\t%s\n", $users if ($users);
		print "Defined on file:\t$file\n\n";
		print "Description:\n\n$desc";
	}
}


#
# Parses all ABI files located at $prefix dir
#
find({wanted =&gt;\&amp;parse_abi, no_chdir =&gt; 1}, $prefix);

print STDERR Data::Dumper-&gt;Dump([\%data], [qw(*data)]) if ($debug);

#
# Handles the command
#
if ($cmd eq "rest") {
	output_rest;
} elsif ($cmd eq "search") {
	search_symbols;
}


__END__

=head1 NAME

abi_book.pl - parse the Linux ABI files and produce a ReST book.

=head1 SYNOPSIS

B&lt;abi_book.pl&gt; [--debug] [--man] [--help] [--dir=&lt;dir&gt;] &lt;COMAND&gt; [&lt;ARGUMENT&gt;]

Where &lt;COMMAND&gt; can be:

=over 8

B&lt;search&gt; [SEARCH_REGEX] - search for [SEARCH_REGEX] inside ABI

B&lt;rest&gt;                  - output the ABI in ReST markup language

B&lt;validate&gt;              - validate the ABI contents

=back

=head1 OPTIONS

=over 8

=item B&lt;--dir&gt;

Changes the location of the ABI search. By default, it uses
the Documentation/ABI directory.

=item B&lt;--debug&gt;

Put the script in verbose mode, useful for debugging. Can be called multiple
times, to increase verbosity.

=item B&lt;--help&gt;

Prints a brief help message and exits.

=item B&lt;--man&gt;

Prints the manual page and exits.

=back

=head1 DESCRIPTION

Parse the Linux ABI files from ABI DIR (usually located at Documentation/ABI),
allowing to search for ABI symbols or to produce a ReST book containing
the Linux ABI documentation.

=head1 EXAMPLES

Search for all stable symbols with the word "usb":

=over 8

$ scripts/get_abi.pl search usb --dir Documentation/ABI/stable

=back

Search for all symbols that match the regex expression "usb.*cap":

=over 8

$ scripts/get_abi.pl search usb.*cap

=back

Output all obsoleted symbols in ReST format

=over 8

$ scripts/get_abi.pl rest --dir Documentation/ABI/obsolete

=back

=head1 BUGS

Report bugs to Mauro Carvalho Chehab &lt;mchehab+samsung@kernel.org&gt;

=head1 COPYRIGHT

Copyright (c) 2016-2019 by Mauro Carvalho Chehab &lt;mchehab+samsung@kernel.org&gt;.

License GPLv2: GNU GPL version 2 &lt;http://gnu.org/licenses/gpl.html&gt;.

This is free software: you are free to change and redistribute it.
There is NO WARRANTY, to the extent permitted by law.

=cut
</pre></body></html>